Mall:Maplink/Regionstyrelsens ordförande

[visa] [redigera] [rensa sidcachen]

Dokumentation

---

Användning

Denna karta kan inkluderas på sidor där man vill visa alla aktuella landshövdingar.

SPARQL-fråga

Detta är frågan som exekveras i kartan:

SELECT ?id ?head (SAMPLE(?fill) as ?fill) (concat('[[w:sv:', substr(str(?link),31,500),  '{{!}}', ?headLabel, ']]') as ?title) (concat(?regionLabel, '\\n', ?img_) as ?description) 
WHERE { 
  ?admboard wdt:P31 wd:Q1754161 ; 
            wdt:P1313 ?title . 
  ?head wdt:P39 ?title ;
        p:P39 ?hold . 
  ?hold ps:P39 ?title; 
        pq:P580 ?start . 
  ?id wdt:P150 ?admboard ; 
      wdt:P31 wd:Q200547 .
  FILTER NOT EXISTS { ?hold pq:P582 []} 
  OPTIONAL { ?head wdt:P102 ?party . 
            ?party wdt:P465 ?f. } 
  BIND(IF(BOUND(?f),?f,'DDDDDD') AS ?f) BIND((concat('#',?f)) as ?fill) 
  SERVICE wikibase:label { bd:serviceParam wikibase:language 'sv' . 
                          ?head rdfs:label ?headLabel . 
                          ?admboard rdfs:label ?regionLabel . } 
  OPTIONAL { ?head wdt:P18 ?img . }
  BIND(COALESCE(CONCAT('[[File:', substr(str(?img), 52, 500), '{{!}}200px]]'),'') AS ?img_)
  OPTIONAL { ?link1 schema:about ?head ; 
                    schema:isPartOf <https://sv.wikipedia.org/> . } 
  ?link2 schema:about ?admboard ; 
         schema:isPartOf <https://sv.wikipedia.org/> . 
  BIND(IF(BOUND(?link1),?link1,?link2) AS ?link) 
} GROUP BY ?id ?head ?headLabel ?img_ ?link ?regionLabel

?admboard är alla region i Sverige (Q1754161) och används för att ta reda på regeringschefens ämbete (P1313) för dem som lagras i ?title.

Därefter används dessa för att ta reda på alla som har befattning (P39) med detta och spara dessa som ?head. Dessa behöver kontrolleras så att de har ett startdatum, men inte ett slutdatum.

Eftersom regionerna inte finns i OpenStreetMap, men har samma yta som länen slås det upp vilket län regionen ligger i och det sparas i ?id.

Om möjligt hämtas personens partitillhörighet och färgvärdet för partiet, som konverteras till färgen att använda på kartan som lagras i ?fill.

Etiketterna för både personen och regionen hämtas.

Slutligen skapas länkar till personen och regionen och formaterar för inkludering.

Underhåll

För att hålla kartan uppdaterad behöver man se till att en avgående ordförande får ett slutdatum satt i sin befattning (med hjälp av bestämningsord). Den tillträdande ordföranden behöver få befattningen, som måste ha ett startdatum. Om personen har en dokumenterad partitillhörighet, ange den med tillhör politiskt parti (P102) så färgläggs kartan automatiskt.

Parametrar

Mallen har inga parametrar.

Ovanstående dokumentation transkluderas från sidan ”Mall:Maplink/Regionstyrelsens ordförande/dok”. Kategorier ska placeras på den dokumentationssidan.